SimCity 2000 Loader for Windows XP

Discussions, suggestions and comments about the SimCity franchise in general
Ghidra
Posts: 1
Joined: Tue Nov 24, 2009 9:48 am

SimCity 2000 Loader for Windows XP

Postby Ghidra » Tue Nov 24, 2009 9:51 am

Hi folks,

I have been looking around on the Internet for an update to the Windows 95 version of SimCity 2000 so that it runs properly under Windows XP. As some of you probably know, the game doesn't work very well on newer versions of Windows: the graphics don't animate properly, the program has to be reinstalled entirely for different Windows user accounts that want to play it, and personal files can be overwritten when these reinstallations occur. It's just a hassle and not worth the trouble.

Once I figured out that the animation problems could be fixed by enabling compatability mode for Windows 95 and forcing 256 colors, I started thinking about coming up with a VBScript that would automate this process along with some other things that would allow the game to function normally on Windows XP. The end result turned out quite well and, once this script is executed, the SimCity 2000 program functionality is updated in the following ways:

    A personalized "SimCity 2000" save folder is created in the user's My Documents folder; the program now defaults to this folder as its save location (this is actually an option, and if it is disabled the user's My Documents folder becomes the default save path)
    All SimCity 2000 registry keys are created and configured for the currently logged on user; this ensures that a reinstallation of the program is never required in order for it to be able to run (installation/configuration errors will never occur again when the game is launched, regardless of how many different users want to play)
    At startup, the current user is prompted for his/her CDRom drive letter (in case you want/need access to the additonal features on the CD), his/her Mayor Name and his/her Company Name; this information is individualized for each user account (for example, Judy can be "Mayor Judy" when she is logged on with her Windows account and Tony can be "Mayor Tony" when he is logged on with his Windows account, the game now keeps track of these unique characteristics and doesn't overwrite anything)
    This script copies itself into the Game installation folder and is used as a loader for the SIMCITY.EXE program (this is what ensures that individual user settings are always configured and stored properly)
    A new program shortcut is created for the "SimCity 2000" program, pointing instead to "%programfiles%\Maxis\SimCity 2000\SimCity2000.vbs"; an updated Windows XP type shortcut is also created for the "SimCity Urban Renewal Kit" program (however, this VBScript is not used as a loader for WINSCURK.EXE)
    Many portions of this script can be configured for your own specific needs and configuration type


I have only tested this with the SimCity 2000 Special Edition package, but I imagine it will also work with other Windows 95 versions (if not in its default state, then probably with a little careful tweaking). However, it works fantastically with the SE version, and serves as the program update I had been hoping to find for quite some time now. I haven't tested this with Windows 2000, Vista or 7, but I imagine that it will at least work with Windows 2000, if not the other two as well.

Here it is. Copy and paste into notepad, make any desired changes to the options near the top, and save as a .VBS file. Make sure SimCity 2000 is installed, double click the VBS file and you're all set. Also, since I'm not sure where all the SimCity websites are on the Net, would you guys mind distributing this for me to all the appropriate sites/channels/people/etc?

EDIT - Updated the script a little bit. This morning I noticed a few things that I should have fixed before posting last night.

Code: Select all

'   *****************************************************************************************************************************
'   Script Name:
'      SimCity 2000 Special Edition; Configuration and Execution Script.vbs
'   Description:
'      > System and user configuration script for running SimCity 2000 on Windows XP systems
'   Update History:
'      November 23, 2009 (CPJ)
'         - Completed v1
'   *****************************************************************************************************************************
'   Editor and Viewing Settings:
'      Notepad++
'      Consolas Font (10 pt.)
'      1024x768 resolution
'
'   Explanation of comment bullets:
'      >   Title/Description
'      +   Instructions on use and allowable configurations/settings/values
'      *   Related information and resources
'      #   Supplemental notes
'      -   Organizational bullet
'      '   General descriptive comment
'

Option Explicit
' + Comment next line to enable debug mode
On Error Resume Next

Const HKEY_CLASSES_ROOT       = &H80000000
Const HKEY_CURRENT_USER       = &H80000001
Const HKEY_LOCAL_MACHINE       = &H80000002

Dim objShell, objFSO, objRegistry, objCreateLink
Dim strComputerName, strTargetFolder, strRegistryValue
Dim strDocumentsPath, strInstallationPath, strCDRomDrive, strMayorName, strCompanyName

strComputerName = "."

Set objShell      = CreateObject("WScript.Shell")
Set objFSO         = CreateObject("Scripting.FileSystemObject")
Set objRegistry      = GetObject("winmgmts:\\" & strComputerName & "\" & "root\default:StdRegProv")

'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
'   > Configure script behavior (default values should be appropriate for most users)
'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

' + Set appropriate path to user's My Documents folder
strDocumentsPath   = objShell.ExpandEnvironmentStrings("%userprofile%\My Documents")
' + Set appropriate path to the system's SimCity 2000 installation folder
strInstallationPath   = objShell.ExpandEnvironmentStrings("%programfiles%\Maxis\SimCity 2000")

' > Create a Save Game folder within the current user's My Documents folder
' + Add/Remove comments to the next three lines of code to enable/disable this feature
If objFSO.FolderExists(strDocumentsPath & "\" & "SimCity 2000") <> True Then
   objFSO.CreateFolder strDocumentsPath & "\" & "SimCity 2000"
End If

' > Check to see if this script has already been installed; if so, do not recreate program shortcuts
If objFSO.FileExists(strInstallationPath & "\" & "SimCity2000.vbs") <> True Then
'   > Create SimCity 2000 shortcuts for All Users
'   + Add/Remove comments to enable/disable a command
   'Call MakeShortcutSimCity2000(objShell.SpecialFolders("AllUsersDesktop"))
   'Call MakeShortcutSimCityUrbanRenewalKit(objShell.SpecialFolders("AllUsersDesktop"))
   'If objFSO.FolderExists(objShell.SpecialFolders("AllUsersPrograms") & "\" & "SimCity 2000") <> True Then
      'objFSO.CreateFolder(objShell.SpecialFolders("AllUsersPrograms") & "\" & "SimCity 2000")
      'Call MakeShortcutSimCity2000(objShell.SpecialFolders("AllUsersPrograms") & "\" & "SimCity 2000")
      'Call MakeShortcutSimCity2000Help(objShell.SpecialFolders("AllUsersPrograms") & "\" & "SimCity 2000")
      'Call MakeShortcutSimCityUrbanRenewalKit(objShell.SpecialFolders("AllUsersPrograms") & "\" & "SimCity 2000")
      'Call MakeShortcutSimCityURKHelp(objShell.SpecialFolders("AllUsersPrograms") & "\" & "SimCity 2000")
   'End If

'   > Create SimCity 2000 shortcuts for Current User
'   + Add/Remove comments to enable/disable a command
   Call MakeShortcutSimCity2000(objShell.SpecialFolders("Desktop"))
   'Call MakeShortcutSimCityUrbanRenewalKit(objShell.SpecialFolders("Desktop"))
   If objFSO.FolderExists(objShell.SpecialFolders("Programs") & "\" & "SimCity 2000") <> True Then
      objFSO.CreateFolder(objShell.SpecialFolders("Programs") & "\" & "SimCity 2000")
      Call MakeShortcutSimCity2000(objShell.SpecialFolders("Programs") & "\" & "SimCity 2000")
      Call MakeShortcutSimCity2000Help(objShell.SpecialFolders("Programs") & "\" & "SimCity 2000")
      Call MakeShortcutSimCityUrbanRenewalKit(objShell.SpecialFolders("Programs") & "\" & "SimCity 2000")
      Call MakeShortcutSimCityURKHelp(objShell.SpecialFolders("Programs") & "\" & "SimCity 2000")
   End If
End If

'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
'   > SimCity 2000 Special Edition registry entries for HKCR
'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

objRegistry.GetStringValue HKEY_CLASSES_ROOT, ".sc2", "", strRegistryValue
If IsNull(strRegistryValue) Then
   objRegistry.CreateKey HKEY_CLASSES_ROOT, ".sc2"
   objRegistry.SetStringValue HKEY_CLASSES_ROOT, ".sc2", "", "SimCity2000.Document.City"
   objRegistry.SetStringValue HKEY_CLASSES_ROOT, ".sc2", "Content Type", "application/schdpl32"
   objRegistry.SetStringValue HKEY_CLASSES_ROOT, ".sc2", "NoOpen", ""
   objRegistry.CreateKey HKEY_CLASSES_ROOT, ".sc2\PersistentHandler"
   objRegistry.SetStringValue HKEY_CLASSES_ROOT, ".sc2\PersistentHandler", "", "{098f2470-bae0-11cd-b579-08002b30bfeb}"
   objRegistry.CreateKey HKEY_CLASSES_ROOT, ".sc2\SchedulePlus.Application.7"
   objRegistry.CreateKey HKEY_CLASSES_ROOT, ".sc2\SchedulePlus.Application.7\ShellNew"
End If

objRegistry.GetStringValue HKEY_CLASSES_ROOT, ".scn", "", strRegistryValue
If IsNull(strRegistryValue) Then
   objRegistry.CreateKey HKEY_CLASSES_ROOT, ".scn"
   objRegistry.SetStringValue HKEY_CLASSES_ROOT, ".scn", "", "SimCity2000.Document.Scenario"
End If

objRegistry.GetStringValue HKEY_CLASSES_ROOT, ".mif", "", strRegistryValue
If IsNull(strRegistryValue) Then
   objRegistry.CreateKey HKEY_CLASSES_ROOT, ".mif"
   objRegistry.SetStringValue HKEY_CLASSES_ROOT, ".mif", "", "SimCity2000.Document.TileSet"
End If

'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
'   > SimCity 2000 Special Edition registry entries for HKLM
'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Maxis\SimCity 2000® Special Edition\1.0"

objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.City"
objRegistry.SetStringValue HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.City", "", "SimCity 2000 City"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.City\DefaultIcon"
objRegistry.SetStringValue HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.City\DefaultIcon", "", strInstallationPath & "\" & "SimCity.exe,1"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.City\shell"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.City\shell\open"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.City\shell\open\command"
objRegistry.SetStringValue HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.City\shell\open\command", "", strInstallationPath & "\" & "SimCity.exe %1"

objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.Scenario"
objRegistry.SetStringValue HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.Scenario", "", "SimCity 2000 Scenario"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.Scenario\DefaultIcon"
objRegistry.SetStringValue HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.Scenario\DefaultIcon", "", strInstallationPath & "\" & "SimCity.exe,2"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.Scenario\shell"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.Scenario\shell\open"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.Scenario\shell\open\command"
objRegistry.SetStringValue HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.Scenario\shell\open\command", "", strInstallationPath & "\" & "SimCity.exe %1"

objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.TileSet"
objRegistry.SetStringValue HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.TileSet", "", "SimCity 2000 Scenario"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.TileSet\DefaultIcon"
objRegistry.SetStringValue HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.TileSet\DefaultIcon", "", strInstallationPath & "\" & "WinScurk.exe,1"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.TileSet\shell"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.TileSet\shell\open"
objRegistry.CreateKey HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.TileSet\shell\open\command"
objRegistry.SetStringValue HKEY_LOCAL_MACHINE, "Software\Classes\SimCity2000.Document.TileSet\shell\open\command", "", strInstallationPath & "\" & "WinScurk.exe %1"

'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
'   > SimCity 2000 Special Edition registry entries for HKCU
'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

objRegistry.GetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Localize", "Language", strRegistryValue
If IsNull(strRegistryValue) Then
   objRegistry.CreateKey HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Localize"
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Localize", "Language", "USA"
End If

objRegistry.GetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Options", "Speed", strRegistryValue
If IsNull(strRegistryValue) Then
   objRegistry.CreateKey HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Options"
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Options", "Speed", 2
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Options", "Sound", 1
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Options", "Music", 1
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Options", "AutoGoto", 1
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Options", "AutoBudget", 0
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Options", "Disasters", 1
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Options", "AutoSave", 0
End If

objRegistry.GetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "Cities", strRegistryValue
If IsNull(strRegistryValue) Then
   strCDRomDrive = InputBox("Please input the drive letter for your CDROM (for example: ""D:"")", "Input CDRom Letter", "D:")
   objRegistry.CreateKey HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths"
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "Cities", strInstallationPath & "\" & "Cities"
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "Data", strInstallationPath & "\" & "Data"
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "Goodies", strCDRomDrive & "\WIN95\SC2K\..\Goodies"
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "Graphics", strInstallationPath & "\" & "Bitmaps"
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "Home", strInstallationPath
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "Music", strInstallationPath & "\" & "Sounds"
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "Scenarios", strInstallationPath & "\" & "Scenario"
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "TileSets", strInstallationPath & "\" & "ScurkArt"

'   # The "SaveGame" path points to the newly created "SimCity 2000" folder within the user's My Documents folder, if it has been
'      created; otherwise, the standard My Documents folder path is assigned
   If objFSO.FolderExists(strDocumentsPath & "\" & "SimCity 2000") Then
      objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "SaveGame", strDocumentsPath & "\" & "SimCity 2000"
   Else
      objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Paths", "SaveGame", strDocumentsPath
   End If
End If

objRegistry.GetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Registration", "Company Name", strRegistryValue
If IsNull(strRegistryValue) Then
   strMayorName = InputBox("Please input your name as SimCity 2000 Mayor (for example: ""Mayor McSim"")", "Input Mayor Name", "Mayor McSim")
   strCompanyName = InputBox("Please input your SimCity 2000 company name (for example: ""Maxis"")", "Input Company Name", "Maxis")
   objRegistry.CreateKey HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Registration"
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Registration", "Company Name", strCompanyName
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Registration", "Mayor Name", strMayorName
End If

objRegistry.GetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\SCURK", "CycleColors", strRegistryValue
If IsNull(strRegistryValue) Then
   objRegistry.CreateKey HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\SCURK"
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\SCURK", "CycleColors", 1
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\SCURK", "GridHeight", 2
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\SCURK", "GridWidth", 2
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\SCURK", "ShowClipRegion", 0
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\SCURK", "ShowDrawGrid", 0
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\SCURK", "SnapToGrid", 0
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\SCURK", "Sound", 1
End If

objRegistry.GetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Version", "SimCity 2000", strRegistryValue
If IsNull(strRegistryValue) Then
   objRegistry.CreateKey HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Version"
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Version", "SCURK", 256
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Version", "SimCity 2000", 256
End If

objRegistry.GetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Windows", "Display", strRegistryValue
If IsNull(strRegistryValue) Then
   objRegistry.CreateKey HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Windows"
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Windows", "Color Check", 0
   objRegistry.SetDWORDValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Windows", "Last Color Depth", 32
   objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Maxis\SimCity 2000\Windows", "Display", "8 1"
End If

'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
'   > Finalize configuration and launch game
'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

' > Enforce Windows XP compatibility mode settings (Windows 95 and 256 color modes)
objRegistry.CreateKey HKEY_CURRENT_USER, "Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers"
objRegistry.SetStringValue HKEY_CURRENT_USER, "Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers", strInstallationPath & "\" & "SIMCITY.EXE", "WIN95 256COLOR"

' > Copy this script to the SimCity 2000 installation folder
If objFSO.FileExists(strInstallationPath & "\" & "SimCity2000.vbs") <> True Then
   objFSO.CopyFile WScript.ScriptFullName, ".\SimCity2000.vbs"
   objFSO.MoveFile ".\SimCity2000.vbs", strInstallationPath & "\"
End If

' > Execute SimCity 2000 program
objShell.Run """" & strInstallationPath & "\" & "simcity.exe" & """"

'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
'   > Subroutines to create updated SimCity 2000 Program Shortcuts
'   /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

Sub MakeShortcutSimCity2000(strTargetFolder)
'   > SimCity 2000 Special Edition execution script
'   # To function properly in Windows XP, this new shortcut must replace the original shortcut created by the SimCity 2000
'      installation
   Set objCreateLink = objShell.CreateShortcut(strTargetFolder & "\" & "SimCity 2000 Special Edition.lnk")
      objCreateLink.TargetPath      = "%systemroot%\system32\wscript.exe"
      objCreateLink.Arguments         = """" & strInstallationPath & "\" & "SimCity2000.vbs" & """"
      objCreateLink.WindowStyle      = 1
      objCreateLink.Hotkey         = ""
      objCreateLink.IconLocation      = strInstallationPath & "\" & "simcity.exe, 0"
      objCreateLink.Description      = "SimCity 2000 Special Edition"
      objCreateLink.WorkingDirectory   = "%HOMEDRIVE%%HOMEPATH%"
   objCreateLink.Save
End Sub

Sub MakeShortcutSimCityUrbanRenewalKit(strTargetFolder)
'   > SimCity Urban Renewal Kit
   Set objCreateLink = objShell.CreateShortcut(strTargetFolder & "\" & "SimCity Urban Renewal Kit.lnk")
      objCreateLink.TargetPath      = strInstallationPath & "\" & "WINSCURK.EXE"
      objCreateLink.Arguments         = ""
      objCreateLink.WindowStyle      = 1
      objCreateLink.Hotkey         = ""
      objCreateLink.IconLocation      = strInstallationPath & "\" & "WINSCURK.EXE, 0"
      objCreateLink.Description      = "SimCity Urban Renewal Kit"
      objCreateLink.WorkingDirectory   = "%HOMEDRIVE%%HOMEPATH%"
   objCreateLink.Save
End Sub

Sub MakeShortcutSimCity2000Help(strTargetFolder)
'   > SimCity 2000 Help
   Set objCreateLink = objShell.CreateShortcut(strTargetFolder & "\" & "SimCity 2000 Help.lnk")
      objCreateLink.TargetPath      = strInstallationPath & "\" & "SC2USA.HLP"
      objCreateLink.Arguments         = ""
      objCreateLink.WindowStyle      = 1
      objCreateLink.Hotkey         = ""
      objCreateLink.IconLocation      = "%SystemRoot%\system32\SHELL32.dll, 23"
      objCreateLink.Description      = "SimCity 2000 Help"
      objCreateLink.WorkingDirectory   = "%HOMEDRIVE%%HOMEPATH%"
   objCreateLink.Save
End Sub

Sub MakeShortcutSimCityURKHelp(strTargetFolder)
'   > SimCity Urban Renewal Kit Help
   Set objCreateLink = objShell.CreateShortcut(strTargetFolder & "\" & "SimCity URK Help.lnk")
      objCreateLink.TargetPath      = strInstallationPath & "\" & "SCURK.HLP"
      objCreateLink.Arguments         = ""
      objCreateLink.WindowStyle      = 1
      objCreateLink.Hotkey         = ""
      objCreateLink.IconLocation      = "%SystemRoot%\system32\SHELL32.dll, 23"
      objCreateLink.Description      = "SimCity Urban Renewal Kit Help"
      objCreateLink.WorkingDirectory   = "%HOMEDRIVE%%HOMEPATH%"
   objCreateLink.Save
End Sub
Last edited by Ghidra on Tue Nov 24, 2009 5:20 pm, edited 1 time in total.
Reason: Minor Script Update (Added Help shortcuts and a few other minor tweaks)

Return to “SimCity Franchise”

Who is online

Users browsing this forum: No registered users and 2 guests